kay/matrix: fix sliding sync

6 files changed, 167 insertions, 23 deletions

diff --git a/os/kay/modules/matrix-sliding-sync.nix b/os/kay/modules/matrix-sliding-sync.nix
deleted file mode 100644
index a4438c6..0000000
--- a/os/kay/modules/matrix-sliding-sync.nix
+++ /dev/null
@@ -1,18 +0,0 @@
-{ config, ... }:
-
-let
-  domain = config.global.userdata.domain;
-in
-{
-  # sops.secrets."matrix-${domain}/sliding_sync" = {};
-  #
-  # services.matrix-sliding-sync = {
-  #   enable = true;
-  #   environmentFile = config.sops.secrets."matrix-${domain}/sliding_sync".path;
-  #
-  #   settings = {
-  #     SYNCV3_LOG_LEVEL = "warn";
-  #     SYNCV3_SERVER = "http://127.0.0.1:${toString config.services.dendrite.httpPort}";
-  #   };
-  # };
-}
diff --git a/os/kay/modules/matrix/default.nix b/os/kay/modules/matrix/default.nix
new file mode 100644
index 0000000..f81d0d9
--- /dev/null
+++ b/os/kay/modules/matrix/default.nix
@@ -0,0 +1,20 @@
+{ config, ... }: let
+  domain = config.global.userdata.domain;
+in {
+  imports = [
+    ./dendrite.nix
+    ./matrix-sliding-sync.nix
+  ];
+
+  sops.secrets."matrix-${domain}/sliding_sync" = {};
+
+  services.matrix-sliding-sync-dirty = {
+    enable = true;
+    environmentFile = config.sops.secrets."matrix-${domain}/sliding_sync".path;
+
+    settings = {
+      SYNCV3_LOG_LEVEL = "warn";
+      SYNCV3_SERVER = "http://127.0.0.1:${toString config.services.dendrite.httpPort}";
+    };
+  };
+}
diff --git a/os/kay/modules/dendrite.nix b/os/kay/modules/matrix/dendrite.nix
index 71266a5..71266a5 100644
--- a/os/kay/modules/dendrite.nix
+++ b/os/kay/modules/matrix/dendrite.nix
diff --git a/os/kay/modules/matrix/matrix-sliding-sync.nix b/os/kay/modules/matrix/matrix-sliding-sync.nix
new file mode 100644
index 0000000..f4c1426
--- /dev/null
+++ b/os/kay/modules/matrix/matrix-sliding-sync.nix
@@ -0,0 +1,106 @@
+{ config, lib, pkgs, ... }:
+
+let
+  cfg = config.services.matrix-sliding-sync-dirty;
+  matrix-sliding-sync = pkgs.callPackage ../../pkgs/matrix-sliding-sync.nix {};
+in
+{
+  imports = [
+    (lib.mkRenamedOptionModule [ "services" "matrix-synapse" "sliding-sync" ] [ "services" "matrix-sliding-sync" ])
+  ];
+
+  options.services.matrix-sliding-sync-dirty = {
+    enable = lib.mkEnableOption "sliding sync";
+
+    settings = lib.mkOption {
+      type = lib.types.submodule {
+        freeformType = with lib.types; attrsOf str;
+        options = {
+          SYNCV3_SERVER = lib.mkOption {
+            type = lib.types.str;
+            description = ''
+              The destination homeserver to talk to not including `/_matrix/` e.g `https://matrix.example.org`.
+            '';
+          };
+
+          SYNCV3_DB = lib.mkOption {
+            type = lib.types.str;
+            default = "postgresql:///matrix-sliding-sync?host=/run/postgresql";
+            description = ''
+              The postgres connection string.
+              Refer to <https://www.postgresql.org/docs/current/libpq-connect.html#LIBPQ-CONNSTRING>.
+            '';
+          };
+
+          SYNCV3_BINDADDR = lib.mkOption {
+            type = lib.types.str;
+            default = "127.0.0.1:8009";
+            example = "[::]:8008";
+            description = "The interface and port or path (for unix socket) to listen on.";
+          };
+
+          SYNCV3_LOG_LEVEL = lib.mkOption {
+            type = lib.types.enum [ "trace" "debug" "info" "warn" "error" "fatal" ];
+            default = "info";
+            description = "The level of verbosity for messages logged.";
+          };
+        };
+      };
+      default = { };
+      description = ''
+        Freeform environment variables passed to the sliding sync proxy.
+        Refer to <https://github.com/matrix-org/sliding-sync#setup> for all supported values.
+      '';
+    };
+
+    createDatabase = lib.mkOption {
+      type = lib.types.bool;
+      default = true;
+      description = ''
+        Whether to enable and configure `services.postgres` to ensure that the database user `matrix-sliding-sync`
+        and the database `matrix-sliding-sync` exist.
+      '';
+    };
+
+    environmentFile = lib.mkOption {
+      type = lib.types.str;
+      description = ''
+        Environment file as defined in {manpage}`systemd.exec(5)`.
+
+        This must contain the {env}`SYNCV3_SECRET` variable which should
+        be generated with {command}`openssl rand -hex 32`.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    services.postgresql = lib.optionalAttrs cfg.createDatabase {
+      enable = true;
+      ensureDatabases = [ "matrix-sliding-sync" ];
+      ensureUsers = [ {
+        name = "matrix-sliding-sync";
+        ensureDBOwnership = true;
+      } ];
+    };
+
+    systemd.services.matrix-sliding-sync = rec {
+      after =
+        lib.optional cfg.createDatabase "postgresql.service"
+        ++ lib.optional config.services.dendrite.enable "dendrite.service"
+        ++ lib.optional config.services.matrix-synapse.enable config.services.matrix-synapse.serviceUnit;
+      wants = after;
+      wantedBy = [ "multi-user.target" ];
+      environment = cfg.settings;
+      serviceConfig = {
+        DynamicUser = true;
+        EnvironmentFile = cfg.environmentFile;
+        ExecStart = lib.getExe matrix-sliding-sync;
+        StateDirectory = "matrix-sliding-sync";
+        WorkingDirectory = "%S/matrix-sliding-sync";
+        RuntimeDirectory = "matrix-sliding-sync";
+        Restart = "on-failure";
+        RestartSec = "1s";
+      };
+    };
+  };
+}
diff --git a/os/kay/modules/www.nix b/os/kay/modules/www.nix
index 04181d0..6530281 100644
--- a/os/kay/modules/www.nix
+++ b/os/kay/modules/www.nix
@@ -6,8 +6,7 @@ let
 in
 {
   imports = [
-    ./dendrite.nix
-    ./matrix-sliding-sync.nix
+    ./matrix
     ./cgit.nix
   ];
 
@@ -58,7 +57,7 @@ in
           "/.well-known/matrix/client".return = ''
             200 '${builtins.toJSON {
                 "m.homeserver".base_url = "https://${domain}";
-                # "org.matrix.msc3575.proxy".url = "https://${domain}";
+                "org.matrix.msc3575.proxy".url = "https://${domain}";
             }}'
           '';
 
@@ -66,8 +65,8 @@ in
             config.services.dendrite.httpPort
           }";
 
-          # "/_matrix/client/unstable/org.matrix.msc3575/sync".proxyPass =
-          #   "http://${config.services.matrix-sliding-sync.settings.SYNCV3_BINDADDR}";
+          "/_matrix/client/unstable/org.matrix.msc3575/sync".proxyPass =
+            "http://${config.services.matrix-sliding-sync-dirty.settings.SYNCV3_BINDADDR}";
         };
       };
 
diff --git a/os/kay/pkgs/matrix-sliding-sync.nix b/os/kay/pkgs/matrix-sliding-sync.nix
new file mode 100644
index 0000000..17051dc
--- /dev/null
+++ b/os/kay/pkgs/matrix-sliding-sync.nix
@@ -0,0 +1,37 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+}:
+
+buildGoModule rec {
+  pname = "matrix-sliding-sync";
+  version = "0.99.19";
+
+  src = fetchFromGitHub {
+    owner = "matrix-org";
+    repo = "sliding-sync";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-w4VL+MioNeJ/R48Ln9tYaqlfg7NvT3mQs0dWOZTHQK4=";
+  };
+
+  vendorHash = "sha256-THjvc0TepIBFOTte7t63Dmadf3HMuZ9m0YzQMI5e5Pw=";
+
+  subPackages = [ "cmd/syncv3" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.GitCommit=${src.rev}"
+  ];
+
+  # requires a running matrix-synapse
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Sliding sync implementation of MSC3575 for matrix";
+    homepage = "https://github.com/matrix-org/sliding-sync";
+    license = with licenses; [ asl20 ];
+    maintainers = with maintainers; [ sinanmohd ];
+    mainProgram = "syncv3";
+  };
+}