1 files changed, 46 insertions, 0 deletions
diff --git a/home/wayland/pkgs/wayland-scripts/default.nix b/home/wayland/pkgs/wayland-scripts/default.nix
new file mode 100644
index 0000000..bded5e7
--- /dev/null
+++ b/home/wayland/pkgs/wayland-scripts/default.nix
@@ -0,0 +1,46 @@
+{
+  stdenvNoCC,
+  lib,
+  makeWrapper,
+
+  bash,
+  sway,
+  ffmpeg,
+  libnotify,
+}:
+
+stdenvNoCC.mkDerivation {
+  pname = "wayland-scipts";
+  version = "1717572072";
+  src = ./src;
+
+  strictDeps = true;
+  outputs = [ "out" ];
+  buildInputs = [ bash ];
+  nativeBuildInputs = [ makeWrapper ];
+
+  postPatch = ''
+    for sh in bin/*; do
+      patchShebangs --host "$sh"
+    done
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    cp -r ./ $out
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/cwall \
+      --prefix PATH : ${lib.makeBinPath [ ffmpeg libnotify sway ]}
+  '';
+
+  meta = {
+    description = "Wayland scripts for sway";
+    homepage = "https://www.sinanmohd.com";
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ sinanmohd ];
+  };
+}