1 files changed, 55 insertions, 0 deletions
diff --git a/package.nix b/package.nix
new file mode 100644
index 0000000..6fa0b52
--- /dev/null
+++ b/package.nix
@@ -0,0 +1,55 @@
+{
+  lib,
+  cjson,
+  highs,
+  makeWrapper,
+  meson,
+  ninja,
+  nix-eval-jobs,
+  pkg-config,
+  stdenv,
+  uthash,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  name = "evanix";
+
+  src =
+    let
+      fs = lib.fileset;
+    in
+    fs.toSource {
+      root = ./.;
+      fileset = fs.unions [
+        ./src
+        ./tests
+        ./include
+        ./meson.build
+        ./meson_options.txt
+      ];
+    };
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    makeWrapper
+  ];
+  buildInputs = [
+    cjson
+    highs
+    uthash
+  ];
+
+  doCheck = true;
+
+  mesonFlags = [ (lib.mesonOption "NIX_EVAL_JOBS_PATH" (lib.getExe nix-eval-jobs)) ];
+
+  meta = {
+    homepage = "https://git.sinanmohd.com/evanix";
+
+    license = lib.licenses.gpl3;
+    platforms = lib.platforms.all;
+    mainProgram = "evanix";
+
+    maintainers = with lib.maintainers; [ sinanmohd ];
+  };
+})