flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

{
  description = "A Nix build Scheduler";

  inputs.nixpkgs.url = "github:NixOs/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }: let
    lib = nixpkgs.lib;

    forSystem = f: system: f {
      inherit system;
      pkgs = import nixpkgs { inherit system; };
    };

    supportedSystems = lib.platforms.unix;
    forAllSystems = f: lib.genAttrs supportedSystems (forSystem f);
  in {
    devShells = forAllSystems ({ system, pkgs }: {
      default = pkgs.mkShell {
        name = "dev";

        buildInputs = with pkgs; [
          jq
          cjson
          nix-eval-jobs

          pkg-config
          meson
          ninja

          gdb
          ccls
          clang-tools # clang-format
        ];

	shellHook = ''
          export PS1="\033[0;34m[󱄅 ]\033[0m $PS1"
        '';
      };
    });

    packages = forAllSystems ({ system, pkgs }: {
      evanix = pkgs.stdenv.mkDerivation (finalAttrs: {
        pname = "evanix";
        version = self.shortRev or self.dirtyShortRev;

        src = ./.;
        nativeBuildInputs = with pkgs; [
          meson
          ninja
          pkg-config
          makeWrapper
        ];
        buildInputs = with pkgs; [
          cjson
          nix-eval-jobs
        ];

        postInstall = ''
          wrapProgram $out/bin/evanix \
              --prefix PATH : ${lib.makeBinPath [ pkgs.nix-eval-jobs ]}
        '';

        meta = {
          homepage = "https://git.sinanmohd.com/evanix";

          license = lib.licenses.gpl3;
          platforms = supportedSystems;
          mainProgram = "evanix";

          maintainers = with lib.maintainers; [ sinanmohd ];
        };
      });

      default = self.packages.${system}.evanix;
    });
  };
}