blob: 0e284870375ccc5e9ee0a134ad8064b6744ce76b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
{
stdenvNoCC,
lib,
makeWrapper,
bash,
sway,
ffmpeg,
libnotify,
imv,
grim,
slurp,
bemenu,
}:
stdenvNoCC.mkDerivation {
pname = "wayland-scipts";
version = "1717606223";
src = ./src;
strictDeps = true;
outputs = [ "out" ];
buildInputs = [ bash ];
nativeBuildInputs = [ makeWrapper ];
postPatch = ''
for sh in bin/*; do
patchShebangs --host "$sh"
done
'';
installPhase = ''
runHook preInstall
cp -r ./ $out
runHook postInstall
'';
postInstall = ''
wrapProgram $out/bin/cwall \
--prefix PATH : ${
lib.makeBinPath [
ffmpeg
libnotify
sway
]
}
wrapProgram $out/bin/daskpass \
--prefix PATH : ${lib.makeBinPath [ bemenu ]}
wrapProgram $out/bin/ttyasrt \
--prefix PATH : ${lib.makeBinPath [ libnotify ]}
wrapProgram $out/bin/freezshot \
--prefix PATH : ${
lib.makeBinPath [
ffmpeg
sway
grim
slurp
imv
]
}
'';
meta = {
description = "Wayland scripts for sway";
homepage = "https://www.sinanmohd.com";
license = lib.licenses.gpl3;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ sinanmohd ];
};
}
|
